*12345678901234567890123456789012345678901234567890123456789

#INCLUDE	'A:\VAR_DEF.ASM'

* Ex_RPM_1.ASM

* This example program calculates the rotation speed N_100 
* in 100s rpm and converts it to BCD format.

* The program assumes that the times T1 and T2 (in cycles), 
* as well as the number of overflows, NOF,
* have been separately captured and can be found in memory.

* To preserve sign information during computation, 
* the program needs to keep the numbers small. Hence it 
* works in 100s of cycles. The variables T1_100 and T2_100
* are calculated by dividing T1 and T2 by decimal 100.  

* The program calculates TOVFL, the time, in 100s of cycles, 
* taken by the overflows. This is done by repeated addition 
* of ($10000)/100, the duration between 2 overflows, and 
* decrementation of NOF. 

* The total time, T_100, in 100s of cycles, is calculated as
* T_100=TOVFL+T2_100-T1_100

* Finally, the program calculates the hex rotation speed, 
* N_100_HEX, by dividing the 'magic' number 
* 2000000*60/100/100 by the total time, T_100. 

* The subroutine HEX_BCD is invoked to convert the rotation
* speed from hex to BCD format, N_100_BCD. (Note that the 
* subroutine is used with #INCLUDE 'A:\HEX_BCD.ASM', hence 
* you have to have it in the root of your floppy directory).

* NOTE: This is only an exercise. You have to enter the
* values of T1, T2 and NOF yourself. Start with the examples:

* Example 1: T2>T1
* Data: 	NOF=1, T1=$0006, T2=$110c
* Results:	T1_100=$0000, T2_100=$002b, TOVFL=$028b,
*	 	T_100=$02ba, N_100_HEX=$0011, N_100_BCD=17

* Example 2: T2<T1 (same times as Ex.1, but shifted 
*		  over the time line)
* Data:		NOF=2, T1=$ffff, T2=$1105
* Results:	T1_100=$028f, T2_100=$002b, TOVFL=$051e, 
*		T_100=$02ba, N_100_HEX=$0011, N_100_BCD=17

* Define variables
	ORG	DATA
NOF		RMB	1		; number of overflows
T1		RMB	2		; time of 1st capture
T2		RMB	2		; time of 2nd capture
T1_100		RMB	2		; T1/100
T2_100		RMB	2		; T2/100
TOVFL		RMB	2		; time taken by overflows
T_100		RMB	2		; (total time)/100
N_100_HEX	RMB	2		; N in 100 rpm (HEX)
N_100_BCD	RMB	1		; N in 100 rpm (BCD)


* Start main program
	ORG	PROGRAM
START	NOP
*	LDX	#REGBAS		; test only
* divide T1 and T2 by 100 to permit calculation
	LDD	T1		; load T1 in D
	LDX	#100		;
	IDIV			; divide T1 by 100
 	STX	T1_100		; store result in T1_100
	LDD	T2		; load T2 in D
	LDX	#100		;
	IDIV			; divide T2 by 100
 	STX	T2_100		; store result in T2_100

* Calculate time taken by overflows TOVFL through repeated additions
	LDD	#$0000		; zero TOVFL
	STD	TOVFL
	LDAA	NOF		; bypass if NOF=0
	BEQ	LABEL6		;
LABEL5	LDD	TOVFL
	ADDD	#($10000)/100
	STD	TOVFL
	DEC	NOF
	BGT	LABEL5		; 
* Calculate total time in 100s of cycles
LABEL6	LDD	TOVFL		: load time taken by overflows
	ADDD	T2_100		; add 2nd time
	SUBD	T1_100		; subtract 1st time
	STD	T_100		; store in T_100
* Calculate RPM in 100s of rpm's
	LDD	#2000000*60/100/100 ; load magic number in accD
	LDX	T_100		; load time in X
	IDIV			; divide
	STX	N_100_HEX	; store result
* Convert N_100 from Hex to BCD
	LDAA	N_100_HEX+1	; load lower part of N_100 in A			
*	LDX	#REGBAS		; test only
	JSR	HEX_BCD		; call conversion subroutine
	STAA	N_100_BCD	; store result
*	STAA	PORTB,X		; test only
	SWI
#INCLUDE 'A:\HEX_BCD.ASM'

	ORG	RESET	; reset vector
	FDB	START	; set to start of program